ファイルをダウンロードするWSH

指定したURLのファイルをダウンロードするWSH

'--------------------------------------------------------------------------------------
'
'	ファイルをダウンロードするスクリプト
'
'--------------------------------------------------------------------------------------

	''--------------------------------------------------------------------------------------
	'	メイン処理
	''--------------------------------------------------------------------------------------
	'↓出力先フォルダを指定
	Const saveFolder = "C:\Documents and Settings\admin\デスクトップ\新しいフォルダ"

	' ダウンロードするURLの定義 (配列で複数のURLを指定できます)
	Dim aURLList(256)

	aURLList(0) = "http://hogehoge/aaa.zip"
	aURLList(1) = "http://hogehoge/bbb.zip"
	aURLList(2) = "http://hogehoge/ccc.zip"

	'定義したURLの終端までループ
	For Each sURL In aURLList

		If sURL = "" Then
			Exit For
		End If

		call SubDownLoad(sURL)

	Next

	Msgbox "処理が完了しました。"


	''--------------------------------------------------------------------------------------
	'	指定されたURLのファイルをダウンロード
	''--------------------------------------------------------------------------------------
	Sub SubDownLoad(strURL)

		on error resume next

		Dim objweb
		Dim wkFileName
		Dim objADO
		Dim res

		'保存するパスの編集
		wkFileName = split(strURL,"/")			
		saveFilePath = saveFolder & "\" & wkFileName(Ubound(wkFileName))

		err.clear
	
		'GETの発行
		Set objweb = CreateObject("MSXML2.ServerXMLHTTP.6.0")
		objweb.Open "GET", strURL, False
		objweb.Send

		'結果を取得
		res = objweb.responseBody

		'取得した内容をファイルに保存する
		set objADO = CreateObject("ADODB.Stream")

		objADO.Type = 1 
		objADO.Open()
		objADO.Write(res)

		objADO.SaveToFile saveFilePath, 2 	'2:上書き保存
		objADO.Close


		Set objADO = Nothing
		Set objweb = Nothing

	 End Sub